############
# Public IP
############

resource "scaleway_instance_ip" "public_ip" {
  count      = var.INSTANCES_COUNT
  project_id = var.SCW_PROJECT_ID
}

################
# DOMAIN RECORD
################

resource "scaleway_domain_record" "subdomain_record" {
  count    = var.INSTANCES_COUNT
  dns_zone = "daag.alpha.grandlyon.com"
  name     = "${var.ENVIRONMENT}-${count.index}"
  type     = "A"
  data     = scaleway_instance_ip.public_ip[count.index].address
  ttl      = 3600
}

resource "scaleway_domain_record" "host_subdomain_record" {
  count    = var.INSTANCES_COUNT
  dns_zone = "daag.alpha.grandlyon.com"
  name     = "*.${var.ENVIRONMENT}-${count.index}"
  type     = "A"
  data     = scaleway_instance_ip.public_ip[count.index].address
  ttl      = 3600
}

##################################
## Security group - Allowed ports
##################################

resource "scaleway_instance_security_group" "www" {
  project_id              = var.SCW_PROJECT_ID
  name                    = "security-group-${var.ENVIRONMENT}"
  inbound_default_policy  = "drop"
  outbound_default_policy = "accept"

  inbound_rule {
    action = "accept"
    port   = "443"
  }

  inbound_rule {
    action = "accept"
    port   = "22"
  }

}

##############################
## VM Instance - User Machine
##############################

resource "scaleway_instance_server" "user_instance_server" {
  count             = var.INSTANCES_COUNT
  project_id        = var.SCW_PROJECT_ID
  name              = "instance${count.index}-${var.ENVIRONMENT}"
  type              = "DEV1-L"
  image             = "ubuntu_jammy"
  ip_id             = scaleway_instance_ip.public_ip[count.index].id
  security_group_id = scaleway_instance_security_group.www.id

  user_data = {
    project_domain = var.PROJECT_DOMAIN
    atrium_count_index = count.index
    atrium_hostname = scaleway_domain_record.subdomain_record[count.index].name
    atrium_letsencrypt_email = var.LETSENCRYPT_EMAIL
    user_password = var.USER_PASSWORD
    cloud-init = file("../instance-scripts/cloud-init.yml")
  }

  depends_on = [
    scaleway_instance_ip.public_ip,
    scaleway_instance_security_group.www,
    scaleway_domain_record.host_subdomain_record,
    scaleway_domain_record.subdomain_record
  ]
}